.版本 2
.支持库 xplib
.支持库 shell
.支持库 iext
.支持库 eAPI
.程序集 窗口程序集1
.程序集变量 星期, 文本型
.程序集变量 数据, 文本型, , “0”
.程序集变量 价格, 文本型, , “0”
.子程序 __启动窗口_创建完毕
.局部变量 n, 整数型
.局部变量 索引, 整数型
版本 ＝ “网吧消费系统 (V 1.0.2.043)”
_启动窗口.标题 ＝ 版本 ＋ “ 服务端”
.如果真 (OpenEvent (2031619, 假, “wbxfcd_slan”) ≠ 0) ‘ 貌似好像必须是2031619
信息框 (“程序已经在运行!”, #错误图标, “禁止重复运行”)
结束 ()
.如果真结束
CreateEvent (0, 假, 假, “wbxfcd_slan”)
XP风格 (1)
.如果 (文件是否存在 (取特定目录 (#Windows系统目录) ＋ “\Slwbxf.dat”) ＝ 假)
载入 (窗口_关于, , 真)
.否则
是否结束程序 ＝ 假
.如果结束
.如果真 (是否结束程序 ＝ 真)
结束 ()
.如果真结束
.如果真 (文件是否存在 (取运行目录 () ＋ “\Config.ini”) ＝ 假)
写到文件 (取运行目录 () ＋ “\Config.ini”, #配置文件)
.如果真结束
.如果真 (文件是否存在 (取运行目录 () ＋ #数据库goods) ＝ 假)
写到文件 (取运行目录 () ＋ #数据库goods, #数据库文件)
.如果真结束
读取配置文件 ()
超级列表框_客户事件.插入列 (0, “时间”, 126, 1, , )
超级列表框_客户事件.插入列 (1, “机号”, 60, 1, , )
超级列表框_客户事件.插入列 (2, “事件”, 270, 1, , )
置托盘图标 (#logo, “网吧消费系统服务端”)
更新客户机商品 ()
取星期 ()
标签_备用.标题 ＝ “ ≮深蓝 E-mail:lanxine@qq.com QQ:***”
.子程序 取星期
星期 ＝ 到文本 (取星期几 (取现行时间 ()))
.判断开始 (到整数 (星期) ＝ 1)
星期 ＝ “日”
.判断 (到整数 (星期) ＝ 2)
星期 ＝ “一”
.判断 (到整数 (星期) ＝ 3)
星期 ＝ “二”
.判断 (到整数 (星期) ＝ 4)
星期 ＝ “三”
.判断 (到整数 (星期) ＝ 5)
星期 ＝ “四”
.判断 (到整数 (星期) ＝ 6)
星期 ＝ “五”
.判断 (到整数 (星期) ＝ 7)
星期 ＝ “六”
.默认
.判断结束
.子程序 读取配置文件
服务器1.端口 ＝ 到数值 (读配置项 (取运行目录 () ＋ “\Config.ini”, “网吧消费菜单”, “端口”, ))
时钟_清空消息.时钟周期 ＝ 到数值 (读配置项 (取运行目录 () ＋ “\Config.ini”, “网吧消费菜单”, “时间”, )) × 1000
消息 ＝ 读配置项 (取运行目录 () ＋ “\Config.ini”, “网吧消费菜单”, “消息”, )
声音 ＝ 读配置项 (取运行目录 () ＋ “\Config.ini”, “网吧消费菜单”, “声音”, )
msg ＝ 读配置项 (取运行目录 () ＋ “\Config.ini”, “网吧消费菜单”, “msg”, )
是否清除消息 ＝ 读配置项 (取运行目录 () ＋ “\Config.ini”, “网吧消费菜单”, “清除”, )
.如果真 (是否清除消息 ＝ “0”)
时钟_清空消息.时钟周期 ＝ 0
.如果真结束
.如果真 (取文本注册项 (4, “SOFTWARE\Microsoft\Windows\CurrentVersion\Run\网吧消费系统”, ) ＝ 取运行目录 () ＋ “\” ＋ 取执行文件名 ())
选择框1.选中 ＝ 真
.如果真结束
.子程序 _时钟_现行时间_周期事件
标签_现行时间.标题 ＝ “ ” ＋ 到文本 (取现行时间 ()) ＋ “ 星期” ＋ 星期
取星期 ()
.子程序 _按钮1_被单击
载入 (窗口_商品, , 真)
.子程序 _按钮3_被单击
载入 (窗口_系统设置, , 真)
.子程序 _按钮_万年历_被单击
载入 (窗口_万年历, , 真)
.子程序 _超级列表框_客户事件_左键单击表项
.如果真 (超级列表框_客户事件.取标题 (超级列表框_客户事件.现行选中项, 0) ≠ “”)
编辑框_详细.内容 ＝ “ ” ＋ 超级列表框_客户事件.取标题 (超级列表框_客户事件.现行选中项, 0) ＋ #换行符 ＋ “【” ＋ 超级列表框_客户事件.取标题 (超级列表框_客户事件.现行选中项, 1) ＋ “】 ” ＋ 超级列表框_客户事件.取标题 (超级列表框_客户事件.现行选中项, 2) ＋ #换行符
.如果真结束
.子程序 __启动窗口_位置被改变
.判断开始 (_启动窗口.位置 ＝ 2)
置托盘图标 (#logo, “网吧消费系统服务端”)
_启动窗口.可视 ＝ 假
.默认
.判断结束
.子程序 __启动窗口_托盘事件
.参数 操作类型, 整数型
.判断开始 (操作类型 ＝ 2)
_启动窗口.可视 ＝ 真
_启动窗口.位置 ＝ 0
_启动窗口.置托盘图标 ({ }, )
.判断 (操作类型 ＝ 3)
弹出菜单 (菜单, , )
.默认
.判断结束
.子程序 _关于_被选择
载入 (窗口_关于, , 真)
.子程序 _按钮2_被单击
超级列表框_客户事件.全部删除 ()
.子程序 _编辑框_详细_鼠标右键被按下, 逻辑型
.参数 横向位置, 整数型
.参数 纵向位置, 整数型
.参数 功能键状态, 整数型
弹出菜单 (工具, , )
.子程序 _复制_被选择
.局部变量 a, 整数型
置剪辑板文本 (编辑框_详细.被选择文本)
.子程序 _全部复制_被选择
编辑框_详细.起始选择位置 ＝ 0
编辑框_详细.被选择字符数 ＝ -1
编辑框_详细.获取焦点 ()
置剪辑板文本 (编辑框_详细.内容)
.子程序 _时钟_清空消息_周期事件
超级列表框_客户事件.全部删除 ()
.子程序 _服务器1_客户进入
.局部变量 a, 整数型
.计次循环首 (取数组成员数 (数据), a)
服务器1.发送数据 (服务器1.取回客户 (), 数据 [a] ＋ “|” ＋ 价格 [a] ＋ “|”, 5)
.计次循环尾 ()
.如果真 (msg ＝ “1”)
服务器1.发送数据 (服务器1.取回客户 (), “开启自定义消息”, 5)
.如果真结束
.子程序 _服务器1_数据到达
.局部变量 现行时间, 日期时间型
.局部变量 取回文本, 文本型, , “0”
.局部变量 计次, 整数型
.局部变量 索引, 整数型
.局部变量 IP, 文本型, , “0”
.局部变量 主机名, 文本型
现行时间 ＝ 取现行时间 ()
IP ＝ 分割文本 (服务器1.取回客户 (), “:”, )
主机名 ＝ 转换为主机名 (IP [1])
索引 ＝ 超级列表框_客户事件.插入表项 (, , , , , )
超级列表框_客户事件.置标题 (索引, 0, 取时间 ())
超级列表框_客户事件.置标题 (索引, 1, 主机名)
超级列表框_客户事件.置标题 (索引, 2, 到文本 (服务器1.取回数据 ()))
.如果真 (消息 ＝ “1”)
信息框 (“ ” ＋ 取时间 () ＋ #换行符 ＋ “【” ＋ 主机名 ＋ “】” ＋ 到文本 (服务器1.取回数据 ()), 0 ＋ #信息图标, “信息”)
.如果真结束
.如果真 (声音 ＝ “1”)
播放音乐 (取运行目录 () ＋ “\msg.wav”, )
.如果真结束
导出到文件 ()
.子程序 _服务器1_客户离开
服务器1.断开客户 (服务器1.取回客户 ())
.子程序 取时间, 文本型
.局部变量 年, 文本型
.局部变量 月, 文本型
.局部变量 日, 文本型
.局部变量 时, 文本型
.局部变量 分, 文本型
.局部变量 秒, 文本型
年 ＝ 到文本 (取年份 (取现行时间 ()))
月 ＝ 到文本 (取月份 (取现行时间 ()))
日 ＝ 到文本 (取日 (取现行时间 ()))
时 ＝ 到文本 (取小时 (取现行时间 ()))
分 ＝ 到文本 (取分钟 (取现行时间 ()))
秒 ＝ 到文本 (取秒 (取现行时间 ()))
返回 (年 ＋ “-” ＋ 月 ＋ “-” ＋ 日 ＋ “ ” ＋ 时 ＋ “:” ＋ 分 ＋ “:” ＋ 秒)
.子程序 更新客户机商品
清除数组 (数据)
清除数组 (价格)
.如果真 (打开 (取运行目录 () ＋ #数据库goods, , 假, #无限制, , , , ) ＝ 真)
到首记录 ()
.计次循环首 (取记录数 (), )
.如果真 (读 (#是否有货) ＝ “有货”)
加入成员 (数据, 读 (#名称))
加入成员 (价格, 读 (#价格))
.如果真结束
跳过 ()
.计次循环尾 ()
.如果真结束
关闭 (取运行目录 () ＋ #数据库goods)
.子程序 _按钮_打开计算器_被单击
运行 (取特定目录 (#Windows系统目录) ＋ “\calc.exe”, 假, )
.子程序 _按钮4_被单击
信息框 (“需要什么功能请以邮件方式通知我，” ＋ #换行符 ＋ “谢谢支持！” ＋ #换行符 ＋ “≮深蓝 E-mail:lanxine@qq.com”, 0 ＋ #信息图标, “感谢您的使用”)
.子程序 _检查更新_被选择
打开指定网址 (“http://www.lanxinbase.com”)
.子程序 导出到文件
.局部变量 待写出数据, 文本型
.局部变量 i, 整数型
.如果真 (超级列表框_客户事件.取表项数 () ＞ -1)
.计次循环首 (超级列表框_客户事件.取表项数 (), i)
待写出数据 ＝ 待写出数据 ＋ #换行符 ＋ “–>” ＋ “时间: ” ＋ 超级列表框_客户事件.取标题 (i － 1, 0) ＋ “ 机号: ” ＋ 超级列表框_客户事件.取标题 (i － 1, 1) ＋ “ 事件: ” ＋ 超级列表框_客户事件.取标题 (i － 1, 2) ＋ #换行符
.计次循环尾 ()
.如果真 (文件是否存在 (取运行目录 () ＋ “\log”) ＝ 假)
创建目录 (取运行目录 () ＋ “\log”)
.如果真结束
写到文件 (取运行目录 () ＋ “\log\” ＋ 到文本 (取年份 (取现行时间 ())) ＋ 到文本 (取月份 (取现行时间 ())) ＋ 到文本 (取日 (取现行时间 ())) ＋ “.log”, 到字节集 (待写出数据))
.如果真结束
.子程序 _按钮5_被单击
运行 (取特定目录 (#Windows安装目录) ＋ “NOTEPAD.EXE ” ＋ 取运行目录 () ＋ “\log\” ＋ 到文本 (取年份 (取现行时间 ())) ＋ 到文本 (取月份 (取现行时间 ())) ＋ 到文本 (取日 (取现行时间 ())) ＋ “.log”, 假, )
.子程序 _选择框1_被单击
.判断开始 (选择框1.选中 ＝ 真)
写注册项 (4, “SOFTWARE\Microsoft\Windows\CurrentVersion\Run\网吧消费系统”, 取运行目录 () ＋ “\” ＋ 取执行文件名 ())
.默认
删除注册项 (4, “SOFTWARE\Microsoft\Windows\CurrentVersion\Run\网吧消费系统”)
.判断结束
.子程序 _显示_被选择
_启动窗口.可视 ＝ 真
_启动窗口.位置 ＝ 0
_启动窗口.置托盘图标 ({ }, )
.子程序 _退出_被选择
时钟_清空消息.时钟周期 ＝ 0
时钟_现行时间.时钟周期 ＝ 0
_启动窗口.置托盘图标 ({ }, )
结束 ()
